~Comment
 Reads an ascii file sequentially.  One useful application
 of this (what it was put in for, actually) is to add a file of raw fone
 numbers to a fonefile while interviewing is going on.  Just read the
 file and pass the numbers into the fonefile with the PHONE,A question.

>purgesame
>halt error

~Prep compile -specs

[phoneadd, 2000, "Read an ascii file", qffname = $addfone, allowabort ]

{ !goto around }      '' need to convince the compiler that we are
{ !phone, 4 }         '' really allowed to have a !PHONE question
{around: !goto }      '' here (The PHONE,A below)

{errcode: .1 HIDE  !var }

{buf: .70 HIDE     !var }

{filename: .30
\aType the name of the file to read\_..............................
!var }

{read: !zspc, 11, 6, errcode, filename, buf }

{!if [errcode$] = " "
!goto rok }

{rbad:
\aread failed.  Error code return: (\|errcode)
!disp }

{ !goto done }

{rok:
\aHere is buf (70 columns wide)
          1         2         3         4         5         6         7
 1234567890123456789012345678901234567890123456789012345678901234567890
(\|buf)
!disp }

{ !phone, a, buf }

{ !goto read }

{done:
\aThat's all, folks
!disp }

{!spc,b }   ''So don't save any data/quota, etc.

~End