~Comment

  Example of how to use a repeat to replicate what the old !loop use to do.
  
  1) Set up a >repeat to execute the block of questions as many times as you need/want
        Be sure to use a repeat variable so you create unique lable names for each
        iteration of the repeat.
  2) Skip out of the repeat block if you have already gone through the repeat as many
        times as there were answers given to the controlling question
  3) Instead of just referencing the loop controller on back references, use the \#(label
        syntax and make sure you reference the current itaration.

>Delete home_made_loop.quo
>Delete home_made_loop.tr
>Purgesame
~Prep Compile
[home_made_loop]

'This is original question. Order of mention here will determine ordcer in which follow up
'questions are asked
{Q1:

Which brands have you used recently?

!Fld,,7
01 Brand A
02 Brand B
03 Brand C
04 Brand D
05 Brand E
06 Brand F
07 Brand G
(-,skipto Done_Loop) 99 None }  ''Skip out of block if no answers are given


'Set up a repeat to go through the home made loop as many times as you want
>Repeat $A=1,...,7; $B=0,2,...,12

'Skip out if the number_of_responess is less than then loop iteration
{Loop_Interaction_$A:
!If XF(Number_Of_Responses(Q1)) < $A
!Goto, Done_Loop }

'If you want the original response code in line with the rest of the data
'Use an spc,9 to store the current code.  Note, $B above starts at 0
'and has an increment equal to the response code length of Q1
'This is optional since it can be also done in the post processing.
{Code$A: .2
\|Q1+$B.2|
!Spc,9 }

'Set up all the questions here and use the \# notation to pull in the nth answer
{Rating_$A:

This is the follow up rating for \#(Q1,$A,1)

!Fld
1 Good
2 Fair
3 Poor
9 Dk }

'2nd follow up question
{HowLong_$A:

How many years have you been using product \#(Q1,$A,1)

Enter 0-75, DK for Don't Know

!Num,,,0-75,,DK }

'Optional.  Create a hidden question that uses up columns in each iteration.
'This allows for easier addtion of questions in the loop later on
{Pad$A:  .10 hide
!var }

>EndRepeat

'Next question or end of block
{Done_Loop:

You made it to the end

!Display }

~End