~COMMENT
  Sample "Call" questionnaire.  This allows you to create sub-questionnaires
  that are called by this questionnaire.  These sub-questionnaires (children)
  can be called as many times as needed on a given survey.

  For instance, if you asking people about banks they use.  You could create
  an over all demographic questionnaire (Household) and it call a questionnaire
  for each person in the household (People) and then have this questionnaire
  call another questionnaire for each Bank that this person might use.

  There is no effective limit to the number of levels or call questionnaires
  used in a single study.  We have tested 100 sub-questionnaires with upto
  5 levels deep.

  Make sure that you do an SPC,A before the first call question so that a
  Case ID number is assigned for this respondent.  This is necessary to
  tie by all the child interviews to the original parent.

  You can use the local scratch area to pass data from the parent to/from
  any child.  If you do this, be sure to blank the local scratch at the top
  or bottom of the parent questionnaire.

  This particular program creates 3 different QFF files: CALLSUBQFFS,MENTORCHILD,
  SURVENTCHILD. CALLSUBQFFS calls the other two.  You can execute the sub QFFs
  as many times as you need in one parent interview.  There are some counters
  displayed in the interview so you can see how data is passed through the local
  scratch area.


>PURGESAME
~PREP COMPILE -SPECS
[CALLSUBQFFS]

{
THIS IS A CFMC DEMO CALL QUESTIONNAIRE

  <RETURN> TO START INTERVIEW

!DISPLAY }

{!SPC,A }

{TOP: !GEN,B,QNTODO }

{QNTODO:

WHICH PRODUCT DO YOU WANT TO SEE NOW?

!CAT
(SKIPTO GETSURV) 1 SURVENT
(SKIPTO GETMENT) 2 MENTOR
(SKIPTO ALLDONE) 0 NONE }

{GETSURV: !CALL,,SURVENTCHILD }

{
YOU ARE NOW BACK FROM SEEING SURVENT WHAT WILL YOU DO?

!DISPLAY }

{!GOTO, TOP }

{GETMENT: !CALL,,MENTORCHILD }

{
YOU ARE NOW BACK FROM SEEING MENTOR, WHAT WILL YOU DO NOW?

!DISPLAY }

{!GOTO, TOP }

{ALLDONE:  !GOTO }

{MENTIMES: .1  HIDE
!VAR }

{!SPC,L,MENTIMES,1,1 }

{SURTIMES: .1  HIDE
!VAR }

{!SPC,L,SURTIMES,2,1 }

{

YOU HAVE ELECTED TO SKIP OUT OF QUESTIONNAIRE

YOU WENT THROUGH THE MENTOR QFILE \|MENTIMES| TIMES

YOU WENT THROUTH THE SURVENT QFILE \|SURTIMES| TIMES

!DISPLAY }

{!GEN,B,MENTIMES,1 }
{!GEN,B,SURTIMES,1 }
{!SPC,K,1,MENTIMES,2 }

~COMMENT

~PREP COMPILE -SPECS
[MENTORCHILD,200]

{MTIMES: .1   HIDE
!VAR }

{!SPC,L,MTIMES,1,1 }

{MTIMESX:  .1
!EXPR,Z,X([MTIMES]) + 1 }

{TIMES: [MTIMESX]
!FLD,A
1 FIRST
2 SECOND
3 THIRD
4 FOURTH
5 FIFTH
6 SIXTH
7 SEVENTH
? A WHOLE LOT }

{
THIS IS THE INTERNAL MENTOR QUESTIONNAIRE

THIS IS \:TIMES: TIME YOU ARE HERE ON THIS CASE!!!!

!DISPLAY }

{FEATURES:

MENTOR HAS ALL OF THESE FEATURES AND MANY MORE.

WHICH OF THESE DO YOU LIKE?

!FLD,,8
01 WEIGHTING
02 STATISTICAL TESTING
03 RANKING
04 TABLE MANIPULATION
05 INTERFACE WITH WORD PROCESSORS/SPREADSHEETS
06 DATA CLEANING
07 UTILITIES FOR MARGINALS/FILE MANIPULATION
08 DIRECTLY INTERFACES WITH SURVENT
(-) 99 NONE }

{!IF FEATURES(01.08)

WHY DID YOU PICK \:FEATURES: FIRST ?


!TEXT }


{!IF FEATURES(99)

SORRY YOU DIDN'T LIKE ANY OF THE MENTOR FEATURES.

WHAT FEATURES WOULD YOU LIKE?

!TEX }

{MENTAGO:

HOW MANY YEARS AGO DID YOU START USING MENTOR

!NUM,,,0-25 }

{CFMCAGO:

HOW MANY YEARS AGO DID YOU HEAR ABOUT CFMC

!NUM,,,0-30 }

{!SPC,K,1,TIMES,1 }

~COMMENT

~PREP COMPILE -SPECS
[SURVENTCHILD,500]

{MTIMES: .1   HIDE
!VAR }

{!SPC,L,MTIMES,2,1 }

{MTIMESX:  .1
!EXPR,Z,X([MTIMES]) + 1 }

{TIMES: [MTIMESX]
!FLD,A
1 FIRST
2 SECOND
3 THIRD
4 FOURTH
5 FIFTH
6 SIXTH
7 SEVENTH
? A WHOLE LOT }

{
THIS IS THE INTERNAL SURVENT QUESTION

THIS IS \:TIMES: TIME YOU ARE HERE ON THIS CASE!!!!

!DISPLAY }

{FEATURES:

SURVENT HAS ALL OF THESE FEATURES AND MANY MORE.

WHICH OF THESE DO YOU LIKE?

!FLD,,10
01 ROTATIONS
02 SKIP LOGIC
03 COMPLEX QUOTA CHECKING
04 PHONE SYSTEM
05 GRIDS
06 CALL QUESTIONNAIRES (LIKE THIS ONE)
07 RANDOM DATA GENERATION
08 EZWRITER
09 INTERFACES WITH MODEMS/PREDICTIVE DIALERS
10 INTERFACE WITH MENTOR/COSI
(-) 99 NONE }

{!IF FEATURES(99)

SORRY YOU DIDN'T LIKE ANY OF THE SURVENT FEATURES.

WHAT FEATURES WOULD YOU LIKE?

!TEX }

{ RATING:
PLEASE RATE THE SURVENT FEATURES LIST ON A 1-5 SCALE
!FLD
5 GREAT
4 GOOD
3 OKAY
2 POOR
1 WEAK }

{!IF RATING(1,2)

WHY DID YOU RATE THE SURVENT FEATURES LIST \:RATING:?

!TEX }

{!SPC,K,2,TIMES,1 }

~END